// time, temperature, pressure, voltage display
// eventually display to video with MAX7456

// temp/pressure protoshield with:
// DS1631 I2C temp sensor
// MPXAZ6115 pressure sensor
// MCP3202 SPI dual 12 bit ADC

// RTC shield with battery backed DS1307

// video overlay shield with MAX7456

// kg4wsv at or near gmail

#include <WProgram.h>
#include <Wire.h>
#include <avr/pgmspace.h>
#include <DS1307.h>
#include <DS1631.h>

#include "MAX7456.h"
MAX7456 osd;

#define DS1631_ADDRESS 0x48

#define DATAFLASH_CS 8


// print prompts and messages from program flash to save SRAM
void print_prompt_P(const char *data) 
{ 
   while (pgm_read_byte(data) != 0x00) 
     Serial.print(pgm_read_byte(data++)); 
}



int rtc[7];  



// MCP3202 2 channel ADC
// 3202 is different software-wise from 3204/3208 (which are identical)

#define MOSI 11
#define MISO  12
#define SPICLOCK 13
#define SLAVE_SELECT_ADC1 4

int read_adc(byte cs, byte channel)
{
  int adcvalue = 0;
//  byte commandbits = B11000000; //command bits - start, mode, chn (3), dont care (3)
  byte commandbits = B11010000; //command bits - start, mode, chn, MSBF 

  //allow channel selection
//  commandbits|=((channel-1)<<3);
  commandbits|=(channel<<5);

  digitalWrite(cs, LOW); //Select adc
  // setup bits to be written
//  for (int i=7; i>=3; i--){
  for (int i=7; i>=4; i--){
    digitalWrite(MOSI,commandbits&1<<i);
    //cycle clock
    digitalWrite(SPICLOCK, HIGH);
    digitalWrite(SPICLOCK, LOW);    
  }

  digitalWrite(SPICLOCK, HIGH);    //ignores 1 null bit
  digitalWrite(SPICLOCK, LOW);

  //read bits from adc
  for (int i=11; i>=0; i--){
    adcvalue+=digitalRead(MISO)<<i;
    //cycle clock
    digitalWrite(SPICLOCK, HIGH);
    digitalWrite(SPICLOCK, LOW);
  }
  digitalWrite(cs, HIGH); //turn off device
  return adcvalue;
}


/////////////////////////////////////////////////////////////////////////////


void setup()
{
  byte c, tick = 10;

  pinMode(MOSI, OUTPUT);
  pinMode(MISO, INPUT);
  pinMode(SPICLOCK, OUTPUT);
  pinMode(SLAVE_SELECT_ADC1, OUTPUT); 

  digitalWrite(SLAVE_SELECT_ADC1, HIGH); 
  digitalWrite(MOSI, LOW); 
  digitalWrite(SPICLOCK, LOW); 

  pinMode(DATAFLASH_CS, OUTPUT);
  digitalWrite(DATAFLASH_CS, HIGH); //disable device

  pinMode(MAX7456SELECT,OUTPUT);
  digitalWrite(MAX7456SELECT,HIGH); //disable device

  Wire.begin();                    // join I2C bus (address optional for master)
//  Serial.begin(115200);
  Serial.begin(9600);
  
  DS1631_init();

  print_prompt_P(PSTR("temp/pressure/voltage test\n"));
  
  osd.begin();
}


void loop()
{
  byte i;
  int ain[4];
  static int counter=10;
  float pressure, altitude_ft;
  float pressure_lowres, altitude_ft_lowres;
  
  ain[0] = read_adc(SLAVE_SELECT_ADC1, 2);
  ain[1] = read_adc(SLAVE_SELECT_ADC1, 1);
  ain[2] = analogRead(0);
  ain[3] = analogRead(1);

  pressure = (ain_to_v_12(ain[0]) + 0.095*5.0)/(5.0 * 0.009);
  altitude_ft = (1 - pow(pressure*10.0/1013.25, 0.190284)) * 145366.45;

  pressure_lowres = (ain_to_v_10(ain[2]) + 0.095*5.0)/(5.0 * 0.009);
  altitude_ft_lowres = (1 - pow(pressure_lowres*10.0/1013.25, 0.190284)) * 145366.45;
  
  
  osd.home();
  osd.print("temp/pressure/voltage ");
//  osd.blink();
  osd.println("test\n");
//  osd.noBlink();

  osd.print("   ");
  osd.print(time_string()); osd.print(' ');
  osd.println(date_string()); osd.print('\n');
  osd.println(temp_string_C()); osd.print('\n');
 
  osd.println("        12 bit 10 bit");

  osd.print("voltage ");
  osd.print(ain_to_v_12(ain[1]) * (4.0)); osd.print("V ");
  osd.print(ain_to_v_10(ain[3]) * (4.0)); osd.print("V\n");

  osd.print("pressure ");
  osd.print((int)pressure); osd.print("kPa ");
  osd.print((int)pressure_lowres); osd.print("kPa  \n");

  osd.print("altitude ");
  osd.print((int)altitude_ft); osd.print("' ");
  osd.print((int)altitude_ft_lowres); osd.print("'\n");

  osd.print("voltage ");
  osd.print(ain_to_v_12(ain[0])); osd.print("V  ");
  osd.print(ain_to_v_10(ain[2])); osd.print("V\n\n");
 
 
  if (counter--)
    {
      delay(500);
      return;
    }
  else
    {
      counter=10;
    }

  Serial.print(ain[0]); Serial.print(' ');
  Serial.print(ain_to_v_12(ain[0])); Serial.print("V ");

  Serial.print(ain[1]); Serial.print(' ');
  Serial.print(ain_to_v_12(ain[1]) * (4.0)); Serial.print("V ");

  Serial.print(ain[2]); Serial.print(' ');
  Serial.print(ain_to_v_10(ain[2])); Serial.print("V ");

  Serial.print(ain[3]); Serial.print(' ');
  Serial.print(ain_to_v_10(ain[3]) * (4.0)); Serial.print("V ");

  Serial.print(time_string()); Serial.print(' ');
  Serial.print(date_string()); Serial.print(' ');
  
  Serial.print(temp_string_C()); Serial.print(' ');

  Serial.print('\n');

//  delay(500);
}


float ain_to_v_10(int a)
{
  return 5.0 * (float)a / 1024.0;
}

float ain_to_v_12(int a)
{
  return 5.0 * (float)a / 4096.0;
}


// DS1631 code from http://www.local-guru.net/blog/2009/02/02/i2c-thermometer-on-arduino
// mangled beyond recognition by kg4wsv

void DS1631_init()
{
  Wire.beginTransmission(DS1631_ADDRESS);
  // send configuration 
  Wire.send(0xAC);
  Wire.send(B00001111); // 12 bit resolution, pol, oneshot
  Wire.endTransmission();
  delay(10);
}


static char * temp_string_C()
{
  static char temp_str[] = "-000.00C";
  byte i=0, conf;
  int temp, frac;
  
  // begin convert
  Wire.beginTransmission(DS1631_ADDRESS);  
  Wire.send(0x51);
  Wire.endTransmission();  
  delay(10);

  // wait until converting is done
  conf = 0;
  while ( conf & B1000000 != B10000000 ) {
    delay( 100 );
    Wire.beginTransmission(DS1631_ADDRESS);  
    Wire.send(0xAC);  
    Wire.endTransmission();
    conf = Wire.receive();
  }

  // ask for the temperature  
  Wire.beginTransmission(DS1631_ADDRESS);  
  Wire.send(0xAA);  
  Wire.endTransmission();

  // request 2 bytes
  Wire.requestFrom(DS1631_ADDRESS, 2);
  // read first byte 

  temp = Wire.receive();
  // read second byte
  frac = Wire.receive();

  if (temp < 0)
  {
    temp_str[i++] = '-';
    temp = -temp;
  }
  if (temp >= 100)
  {
    temp_str[i++] = temp / 100 + '0';
    temp = temp % 100;
  }
  if (temp >= 10)
  {
    temp_str[i++] = temp / 10 + '0';
    temp %= 10;
  }
  temp_str[i++] = temp % 10 + '0';
  temp_str[i++] = '.';

  frac = 100 * (frac & 0xF0 )/ 256;
  temp_str[i++] = frac / 10 + '0';
  temp_str[i++] = frac % 10 + '0';
  temp_str[i++] = 'C';
  temp_str[i++] = '\0';
  
  return temp_str;
}



static char * time_string()
{
  static char time_str[] = "00:00:00";
  
  RTC.get(rtc,true);

  time_str[0] = rtc[2] / 10 + '0';
  time_str[1] = rtc[2] % 10 + '0';

  time_str[3] = rtc[1] / 10 + '0';
  time_str[4] = rtc[1] % 10 + '0';

  time_str[6] = rtc[0] / 10 + '0';
  time_str[7] = rtc[0] % 10 + '0';
  
  return time_str;
}

static char * date_string()
{
  // US format
  static char date_str[] = "00/00/0000";
  
  RTC.get(rtc,true);

  date_str[0] = rtc[4] / 10 + '0';
  date_str[1] = rtc[4] % 10 + '0';

  date_str[3] = rtc[5] / 10 + '0';
  date_str[4] = rtc[5] % 10 + '0';

  date_str[6] = rtc[6] / 1000 + '0';
  date_str[7] = rtc[6] % 1000 / 100 + '0';
  date_str[8] = rtc[6] % 100 / 10 + '0';
  date_str[9] = rtc[6] % 1000 + '0';
  
  return date_str;
}